## <summary>Apache QPID AMQP messaging server.</summary>

########################################
## <summary>
##	Execute a domain transition to run qpidd.
## </summary>
## <param name="domain">
##	<summary>
##	Domain allowed to transition.
##	</summary>
## </param>
#
interface(`qpidd_domtrans',`
	gen_require(`
		type qpidd_t, qpidd_exec_t;
	')

	corecmd_search_bin($1)
	domtrans_pattern($1, qpidd_exec_t, qpidd_t)
')

#####################################
## <summary>
##	Read and write access qpidd semaphores.
## </summary>
## <param name="domain">
##	<summary>
##	Domain allowed access.
##	</summary>
## </param>
#
interface(`qpidd_rw_semaphores',`
	gen_require(`
		type qpidd_t;
	')

	allow $1 qpidd_t:sem rw_sem_perms;
')

########################################
## <summary>
##	Read and write qpidd shared memory.
## </summary>
## <param name="domain">
##	<summary>
##	Domain allowed access.
##	</summary>
## </param>
#
interface(`qpidd_rw_shm',`
	gen_require(`
		type qpidd_t;
	')

	allow $1 qpidd_t:shm rw_shm_perms;
')

########################################
## <summary>
##	Execute qpidd init script in
##	the initrc domain.
## </summary>
## <param name="domain">
##	<summary>
##	Domain allowed to transition.
##	</summary>
## </param>
#
interface(`qpidd_initrc_domtrans',`
	gen_require(`
		type qpidd_initrc_exec_t;
	')

	init_labeled_script_domtrans($1, qpidd_initrc_exec_t)
')

########################################
## <summary>
##	Read qpidd pid files.  (Deprecated)
## </summary>
## <param name="domain">
##	<summary>
##	Domain allowed access.
##	</summary>
## </param>
#
interface(`qpidd_read_pid_files',`
	refpolicywarn(`$0($*) has been deprecated.')
')

########################################
## <summary>
##	Search qpidd lib directories.
## </summary>
## <param name="domain">
##	<summary>
##	Domain allowed access.
##	</summary>
## </param>
#
interface(`qpidd_search_lib',`
	gen_require(`
		type qpidd_var_lib_t;
	')

	files_search_var_lib($1)
	allow $1 qpidd_var_lib_t:dir search_dir_perms;
')

########################################
## <summary>
##	Read qpidd lib files.
## </summary>
## <param name="domain">
##	<summary>
##	Domain allowed access.
##	</summary>
## </param>
#
interface(`qpidd_read_lib_files',`
	gen_require(`
		type qpidd_var_lib_t;
	')

	files_search_var_lib($1)
	read_files_pattern($1, qpidd_var_lib_t, qpidd_var_lib_t)
')

########################################
## <summary>
##	Create, read, write, and delete
##	qpidd lib files.
## </summary>
## <param name="domain">
##	<summary>
##	Domain allowed access.
##	</summary>
## </param>
#
interface(`qpidd_manage_lib_files',`
	gen_require(`
		type qpidd_var_lib_t;
	')

	files_search_var_lib($1)
	manage_files_pattern($1, qpidd_var_lib_t, qpidd_var_lib_t)
')

########################################
## <summary>
##	All of the rules required to
##	administrate an qpidd environment.
## </summary>
## <param name="domain">
##	<summary>
##	Domain allowed access.
##	</summary>
## </param>
## <param name="role">
##	<summary>
##	Role allowed access.
##	</summary>
## </param>
## <rolecap/>
#
interface(`qpidd_admin',`
	gen_require(`
		type qpidd_t, qpidd_initrc_exec_t, qpidd_var_lib_t;
		type qpidd_runtime_t;
	')

	allow $1 qpidd_t:process { ptrace signal_perms };
	ps_process_pattern($1, qpidd_t)

	init_startstop_service($1, $2, qpidd_t, qpidd_initrc_exec_t)

	files_search_var_lib($1)
	admin_pattern($1, qpidd_var_lib_t)

	files_search_runtime($1)
	admin_pattern($1, qpidd_runtime_t)
')
