## <summary>Statistics collection daemon for filling RRD files.</summary>

########################################
## <summary>
##	All of the rules required to
##	administrate an collectd environment.
## </summary>
## <param name="domain">
##	<summary>
##	Domain allowed access.
##	</summary>
## </param>
## <param name="role">
##	<summary>
##	Role allowed access.
##	</summary>
## </param>
## <rolecap/>
#
interface(`collectd_admin',`
	gen_require(`
		type collectd_t, collectd_initrc_exec_t, collectd_runtime_t;
		type collectd_var_lib_t;
	')

	allow $1 collectd_t:process { ptrace signal_perms };
	ps_process_pattern($1, collectd_t)

	init_startstop_service($1, $2, collectd_t, collectd_initrc_exec_t)

	files_search_runtime($1)
	admin_pattern($1, collectd_runtime_t)

	files_search_var_lib($1)
	admin_pattern($1, collectd_var_lib_t)
')
